subsite::request_email_change (private)

 subsite::request_email_change user_id old_email new_email

Defined in packages/acs-subsite/tcl/email-change-procs.tcl

Store a pending email change and send confirmation to the proposed address.

Parameters:
user_id (required)
old_email (required)
new_email (required)

Partial Call Graph (max 5 caller/called nodes):
packages/acs-subsite/lib/user-info.tcl packages/acs-subsite/ lib/user-info.tcl subsite::request_email_change subsite::request_email_change packages/acs-subsite/lib/user-info.tcl->subsite::request_email_change _ _ (public) subsite::request_email_change->_ acs_mail_lite::send acs_mail_lite::send (public) subsite::request_email_change->acs_mail_lite::send ad_system_owner ad_system_owner (public) subsite::request_email_change->ad_system_owner ad_url ad_url (public) subsite::request_email_change->ad_url db_dml db_dml (public) subsite::request_email_change->db_dml

Testcases:
No testcase defined.
Source code:
    set new_email [string tolower [string trim $new_email]]
    if {$new_email eq "" || [string length $new_email] > 100
        || ![util_email_valid_p $new_email]} {
        error "Invalid email address"
    }
    set token [ns_crypto::randombytes -encoding hex 32]
    set digest [ns_crypto::md string -digest sha256 -encoding hex $token]
    set expires [expr {[clock seconds] + 86400}]
    set base "[string trimright [ad_url] /]/user/email-change-confirm"
    set confirmation_url [export_vars -base $base {token}]

    db_transaction {
        set current_email [db_string email_change_lock_party {
            select email from parties where party_id = :user_id for update
        }]
        if {$current_email ne $old_email
            || [party::get_by_email_not_cached -email $new_email] ne ""} {
            error "Account email changed or proposed email is unavailable"
        }
        db_dml email_change_replace_pending {
            delete from subsite_email_changes where user_id = :user_id
        }
        db_dml email_change_insert_pending {
            insert into subsite_email_changes
                (user_id, old_email, new_email, token_digest, expires_at)
            values (:user_id, :old_email, :new_email, :digest, :expires)
        }
        acs_mail_lite::send -to_addr $new_email -from_addr [ad_system_owner]  -subject [_ acs-subsite.Email_change_confirm]  -body [_ acs-subsite.Email_change_mail_body]
    }
XQL Not present:
Generic, PostgreSQL, Oracle
[ hide source ] | [ make this the default ]
Show another procedure: